openoffice-users-de mailing list archives

Site index · List index
Message view « Date » · « Thread »
Top « Date » · « Thread »
From Jörg Schmidt <joe...@j-m-schmidt.de>
Subject Re: Calc - Umrechnung Dezimalgrad - Minute´ngrad
Date Mon, 06 May 2013 08:30:13 GMT
Hallo,
 
> From: Bauersachs [mailto:konrad.bauersachs@t-online.de] 

> Eine direkte Umwandlung Dezimalkoordinaten in Gradkoordinaten 
> ist mir nicht
> bekannt, ich habe es auf dem Umweg Komma der Dezimalzahl als 
> Trennzeichen
> und Zwischenspeicherung als Textformat gelöst. 
> 
> Soweit so gut. Die fertige Tabelle sieht jetzt etwa so aus:
> 
>     Wadi Hasa  Kerak  37,583  30,933   37°35'0"  30°56'0"
> 
> Hat jemand eine Idee, ob es für Faule irgendwie möglich ist, 
> Dezimalgrad
> direkt in Winkelgrad umzurechnen???

Muss 37,583 denn 37°35'0" ergeben? 
Warum nicht besser 37° 34' 59", denn 37°35'0" = 37,58333 hingegen 37°34'59" =
37,58305.

Falls 37°34'59" dann mit z.B.:

=GANZZAHL(37,583) & "° " & GANZZAHL((37,583-GANZZAHL(37,583))*60) & "' " &
RUNDEN((((37,583-GANZZAHL(37,583))*60)-GANZZAHL((37,583-GANZZAHL(37,583))*60))*60)
& """"

Falls nicht müßte man die Formel halt anpassen indem man zusätzlich rundet.


Wie stellt man solche Formel auf?

Schreibe in A1: 37,583
Schreibe in B1: =GANZZAHL(A1) um die Grade abzutrennen
Schreibe in B2: =A1-B1 um den Rest zu ermitteln
Schreibe in B3: =B2*60 um den Rest in Minuten umzurechnen
Schreibe in B4: =GANZZAHL(B3) um die ganzen Minuten abzutrennen
Schreibe in B5: =B3-B4 um den Rest zu ermitteln
Schreibe in B6: =RUNDEN(B5*60) um die Sekunden zu berechnen

Fasse Grade, Minuten und Sekunden in B7 zusammen:

=B1 & "° " & B4 & "' " & B6 & """"

Ersetze in B7 rekursiv alle Zellenamen durch Einsetzen der Inhalte der Zellen:

=GANZZAHL(A1) & "° " & B4 & "' " & B6 & """"
=GANZZAHL(A1) & "° " & GANZZAHL(B3) & "' " & B6 & """"
=GANZZAHL(A1) & "° " & GANZZAHL(B2*60) & "' " & B6 & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-B1)*60) & "' " & B6 & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " & B6 & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " & RUNDEN(B5*60)
&
""""
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " & RUNDEN((B3-B4)*60)
& """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " &
RUNDEN((B3-GANZZAHL(B3))*60) & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " &
RUNDEN(((B2*60)-GANZZAHL(B2*60))*60) & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " &
RUNDEN((((A1-B1)*60)-GANZZAHL((A1-B1)*60))*60) & """"
=GANZZAHL(A1) & "° " & GANZZAHL((A1-GANZZAHL(A1))*60) & "' " &
RUNDEN((((A1-GANZZAHL(A1))*60)-GANZZAHL((A1-GANZZAHL(A1))*60))*60) & """"
=GANZZAHL(37,583) & "° " & GANZZAHL((37,583-GANZZAHL(37,583))*60) & "' " &
RUNDEN((((37,583-GANZZAHL(37,583))*60)-GANZZAHL((37,583-GANZZAHL(37,583))*60))*60)
& """"



Gruß
Jörg 



---------------------------------------------------------------------
To unsubscribe, e-mail: users-de-unsubscribe@openoffice.apache.org
For additional commands, e-mail: users-de-help@openoffice.apache.org


Mime
View raw message