mesos-commits mailing list archives

Site index · List index
Message view « Date » · « Thread »
Top « Date » · « Thread »
From b...@apache.org
Subject [1/2] git commit: Force disable C++11 in mesos for g++-4.7.
Date Thu, 20 Mar 2014 18:45:21 GMT
Repository: mesos
Updated Branches:
  refs/heads/master 1c15e9879 -> f9ec8b2ac


Force disable C++11 in mesos for g++-4.7.

Review: https://reviews.apache.org/r/19336


Project: http://git-wip-us.apache.org/repos/asf/mesos/repo
Commit: http://git-wip-us.apache.org/repos/asf/mesos/commit/f9ec8b2a
Tree: http://git-wip-us.apache.org/repos/asf/mesos/tree/f9ec8b2a
Diff: http://git-wip-us.apache.org/repos/asf/mesos/diff/f9ec8b2a

Branch: refs/heads/master
Commit: f9ec8b2ac67e397b6856843485124a8be08995c8
Parents: f32acf2
Author: Dominic Hamon <dhamon@twopensource.com>
Authored: Thu Mar 20 11:35:51 2014 -0700
Committer: Benjamin Hindman <benjamin.hindman@gmail.com>
Committed: Thu Mar 20 11:39:55 2014 -0700

----------------------------------------------------------------------
 configure.ac             |  85 +++++++++++---------
 m4/ax_compare_version.m4 | 177 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 225 insertions(+), 37 deletions(-)
----------------------------------------------------------------------


http://git-wip-us.apache.org/repos/asf/mesos/blob/f9ec8b2a/configure.ac
----------------------------------------------------------------------
diff --git a/configure.ac b/configure.ac
index 9a6de87..5404dc2 100644
--- a/configure.ac
+++ b/configure.ac
@@ -165,20 +165,14 @@ AC_ARG_VAR([JAVA_LDFLAGS], [linker flags for JNI])
 
 AC_ARG_VAR([PYTHON], [which Python interpreter to use])
 
-
+AC_MSG_NOTICE([Setting up build environment for ${target_cpu} ${target_os}])
 # Determine the current OS (TODO(benh): Does autotools do this for us?).
 case "${target_os}" in
   linux*)
-    echo ===========================================================
-    echo Setting up build environment for ${target_cpu} ${target_os}
-    echo ===========================================================
     OS_NAME=linux
     LIBS="$LIBS -lrt"
     ;;
   darwin*)
-    echo ===========================================================
-    echo Setting up build environment for ${target_cpu} ${target_os}
-    echo ===========================================================
     OS_NAME=darwin
     ;;
   *)
@@ -196,35 +190,6 @@ AC_PROG_CXX([g++])
 AC_PROG_CC([gcc])
 
 
-# Check the version of gcc and add any flags as appropriate. Note that
-# '-dumpversion' works for clang as well but as of clang 3.3 it
-# reports version 4.2.1 (for gcc backwards compatibility).
-GCC_VERSION="`${CC} -dumpversion`"
-AC_MSG_NOTICE([GCC version: $GCC_VERSION])
-test $? = 0 || AC_MSG_ERROR([failed to determine version of gcc])
-case  "${GCC_VERSION}" in
-  4.4*)
-    echo ===========================================================
-    echo Setting up CXXFLAGS for gcc 4.4.*
-    echo ===========================================================
-    # We fail to build some protobuf generated code with gcc 4.4
-    # without setting -fno-strict-aliasing.
-    CFLAGS="$CFLAGS -fno-strict-aliasing"
-    CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
-  ;;
-  4.8*)
-    echo ===========================================================
-    echo Setting up CXXFLAGS for gcc 4.8.*
-    echo ===========================================================
-    # Boost 1.53.0 won't compile with GCC 4.8 without -Wno-unused-local-typedefs,
-    # and automake doesn't recognize the flag.
-    # TODO(brenden): Remove this when Boost has a resolution.
-    CFLAGS="${CFLAGS} -Wno-unused-local-typedefs"
-    CXXFLAGS="${CXXFLAGS} -Wno-unused-local-typedefs"
-  ;;
-esac
-
-
 # Check if we should try and enable optimizations.
 if test "x$enable_optimize" = "xyes"; then
   # For now, we only turn on optimizations for gcc.
@@ -250,9 +215,55 @@ AC_LANG_POP([C++])
 AC_MSG_RESULT([$CLANG])
 AC_SUBST([CLANG])
 
-# Force C++11 if we're using clang.
+# Force enable C++11 if compiling with clang.
+# Force disable C++11 if compiling with g++-4.7.
 if test "x$CLANG" = "xyes"; then
+  if test "x$with_cxx11" != "xyes"; then
+    AC_MSG_WARN([Force enabling C++11 for Clang build])
+  fi
   with_cxx11=yes
+else
+  # Check the version of gcc and add any flags as appropriate. Note
+  # that '-dumpversion' works for clang as well but as of clang 3.3 it
+  # reports version 4.2.1 (for gcc backwards compatibility).
+  GCC_VERSION="`${CC} -dumpversion`"
+  AC_MSG_NOTICE([GCC version: $GCC_VERSION])
+  test $? = 0 || AC_MSG_ERROR([failed to determine version of gcc])
+
+  # Check for GCC version 4.4.
+  AX_COMPARE_VERSION([$GCC_VERSION], [eq2], [4.4],
+                     [is_gxx44=yes], [is_gxx44=no])
+  if test "x$is_gxx44" = "xyes"; then
+    AC_MSG_NOTICE([Setting up CXXFLAGS for g++-4.4])
+    # We fail to build some protobuf generated code with gcc 4.4
+    # without setting -fno-strict-aliasing.
+    CFLAGS="$CFLAGS -fno-strict-aliasing"
+    CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
+  fi
+
+  # Check for GCC version 4.8.
+  AX_COMPARE_VERSION([$GCC_VERSION], [eq2], [4.8],
+                     [is_gxx48=yes], [is_gxx48=no])
+  if test "x$is_gxx48" = "xyes"; then
+    AC_MSG_NOTICE([Setting up CXXFLAGS for g++-4.8])
+    # Boost 1.53.0 fails to compile with GCC 4.8 without
+    # -Wno-unused-local-typedefs, and automake does not recognize the
+    # flag.
+    # TODO(brenden): Remove this when Boost has a resolution.
+    CFLAGS="${CFLAGS} -Wno-unused-local-typedefs"
+    CXXFLAGS="${CXXFLAGS} -Wno-unused-local-typedefs"
+  fi
+
+  # Check for GCC version == 4.7 and disable C++11. The C++11 version
+  # of libprocess' Future uses features that 4.7 doesn't support. The
+  # non-C++11 version of libprocess' Future uses std::tr1 code that is
+  # only available without-cxx11.
+  AX_COMPARE_VERSION([$GCC_VERSION], [eq2], [4.7],
+                     [is_gxx47=yes], [is_gxx47=no])
+  if test "x$is_gxx47" = "xyes"; then
+    AC_MSG_WARN([Force disabling C++11 for g++-4.7 build])
+    with_cxx11=no
+  fi
 fi
 
 

http://git-wip-us.apache.org/repos/asf/mesos/blob/f9ec8b2a/m4/ax_compare_version.m4
----------------------------------------------------------------------
diff --git a/m4/ax_compare_version.m4 b/m4/ax_compare_version.m4
new file mode 100644
index 0000000..97448f9
--- /dev/null
+++ b/m4/ax_compare_version.m4
@@ -0,0 +1,177 @@
+# ===========================================================================
+#    http://www.gnu.org/software/autoconf-archive/ax_compare_version.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+#   This macro compares two version strings. Due to the various number of
+#   minor-version numbers that can exist, and the fact that string
+#   comparisons are not compatible with numeric comparisons, this is not
+#   necessarily trivial to do in a autoconf script. This macro makes doing
+#   these comparisons easy.
+#
+#   The six basic comparisons are available, as well as checking equality
+#   limited to a certain number of minor-version levels.
+#
+#   The operator OP determines what type of comparison to do, and can be one
+#   of:
+#
+#    eq  - equal (test A == B)
+#    ne  - not equal (test A != B)
+#    le  - less than or equal (test A <= B)
+#    ge  - greater than or equal (test A >= B)
+#    lt  - less than (test A < B)
+#    gt  - greater than (test A > B)
+#
+#   Additionally, the eq and ne operator can have a number after it to limit
+#   the test to that number of minor versions.
+#
+#    eq0 - equal up to the length of the shorter version
+#    ne0 - not equal up to the length of the shorter version
+#    eqN - equal up to N sub-version levels
+#    neN - not equal up to N sub-version levels
+#
+#   When the condition is true, shell commands ACTION-IF-TRUE are run,
+#   otherwise shell commands ACTION-IF-FALSE are run. The environment
+#   variable 'ax_compare_version' is always set to either 'true' or 'false'
+#   as well.
+#
+#   Examples:
+#
+#     AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
+#
+#   would both be true.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
+#
+#   would both be false.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
+#
+#   would be true because it is only comparing two minor versions.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
+#
+#   would be true because it is only comparing the lesser number of minor
+#   versions of the two values.
+#
+#   Note: The characters that separate the version numbers do not matter. An
+#   empty string is the same as version 0. OP is evaluated by autoconf, not
+#   configure, so must be a string, not a variable.
+#
+#   The author would like to acknowledge Guido Draheim whose advice about
+#   the m4_case and m4_ifvaln functions make this macro only include the
+#   portions necessary to perform the specific comparison specified by the
+#   OP argument in the final configure script.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu>;
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 11
+
+dnl #########################################################################
+AC_DEFUN([AX_COMPARE_VERSION], [
+  AC_REQUIRE([AC_PROG_AWK])
+
+  # Used to indicate true or false condition
+  ax_compare_version=false
+
+  # Convert the two version strings to be compared into a format that
+  # allows a simple string comparison.  The end result is that a version
+  # string of the form 1.12.5-r617 will be converted to the form
+  # 0001001200050617.  In other words, each number is zero padded to four
+  # digits, and non digits are removed.
+  AS_VAR_PUSHDEF([A],[ax_compare_version_A])
+  A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  AS_VAR_PUSHDEF([B],[ax_compare_version_B])
+  B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
+  dnl # then the first line is used to determine if the condition is true.
+  dnl # The sed right after the echo is to remove any indented white space.
+  m4_case(m4_tolower($2),
+  [lt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [gt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [le],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],
+  [ge],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],[
+    dnl Split the operator from the subversion count if present.
+    m4_bmatch(m4_substr($2,2),
+    [0],[
+      # A count of zero means use the length of the shorter version.
+      # Determine the number of characters in A and B.
+      ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
+      ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
+
+      # Set A to no more than B's length and B to no more than A's length.
+      A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
+    ],
+    [[0-9]+],[
+      # A count greater than zero means use only that many subversions
+      A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+    ],
+    [.+],[
+      AC_WARNING(
+        [illegal OP numeric parameter: $2])
+    ],[])
+
+    # Pad zeros at end of numbers to make same length.
+    ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
+    B="$B`echo $A | sed 's/./0/g'`"
+    A="$ax_compare_version_tmp_A"
+
+    # Check for equality or inequality as necessary.
+    m4_case(m4_tolower(m4_substr($2,0,2)),
+    [eq],[
+      test "x$A" = "x$B" && ax_compare_version=true
+    ],
+    [ne],[
+      test "x$A" != "x$B" && ax_compare_version=true
+    ],[
+      AC_WARNING([illegal OP parameter: $2])
+    ])
+  ])
+
+  AS_VAR_POPDEF([A])dnl
+  AS_VAR_POPDEF([B])dnl
+
+  dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
+  if test "$ax_compare_version" = "true" ; then
+    m4_ifvaln([$4],[$4],[:])dnl
+    m4_ifvaln([$5],[else $5])dnl
+  fi
+]) dnl AX_COMPARE_VERSION


Mime
View raw message