forrest-dev mailing list archives

Site index · List index
Message view « Date » · « Thread »
Top « Date » · « Thread »
From nicola...@apache.org
Subject cvs commit: xml-forrest/src/core/context/skins/tigris-style/xslt/html book2menu.xsl document2html.xsl site2xhtml.xsl tab2menu.xsl
Date Mon, 22 Dec 2003 09:56:11 GMT
nicolaken    2003/12/22 01:56:11

  Added:       src/core/context/skins/tigris-style/xslt/html book2menu.xsl
                        document2html.xsl site2xhtml.xsl tab2menu.xsl
  Log:
  Adding tigris style skin 1.1, should replace the avalon-tigris skin.
  
  Still needs polishing.
  The CSS, images and scripts (except base forrest ones) are 1-1 copy of the
  tigris version, to help in updating it at a later date.
  
  NOTE: the doctyle is html 1.1 loose transitional, while this skin requires
  a tigris DTD: because of this document fonts render larger.
  
  Revision  Changes    Path
  1.1                  xml-forrest/src/core/context/skins/tigris-style/xslt/html/book2menu.xsl
  
  Index: book2menu.xsl
  ===================================================================
  <?xml version="1.0"?>
  <!--
  book2menu.xsl generates the HTML menu.  See the imported book2menu.xsl for
  details.
  
  $Id: book2menu.xsl,v 1.1 2003/12/22 09:56:11 nicolaken Exp $
  -->
  
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  
    <xsl:import href="../../../common/xslt/html/book2menu.xsl"/>
           
    <xsl:template match="book">
      <div class="menu">
          <div class="body">
            <xsl:apply-templates select="menu"/>
          </div>
      </div>
      
      <div class="strut">&#160;</div>
    </xsl:template>
  
    <xsl:template match="menu">
      <div>
        <a href="{@href}"><xsl:value-of select="@label"/></a>
        <xsl:apply-templates/>
      </div>
    </xsl:template>
  
    <xsl:template match="menu-item[@type='hidden']"/>
  
    <xsl:template match="menu-item">
      <div>
        <a href="{@href}"><xsl:value-of select="@label"/></a>
        <xsl:apply-templates/>
      </div>
    </xsl:template>
    
    <xsl:template name="selected">
      <div class="selfref">
        <xsl:value-of select="@label"/>
        <xsl:apply-templates/>
      </div>
    </xsl:template>
  
    <xsl:template name="print-external">
        <xsl:apply-imports/>
    </xsl:template>
    
  </xsl:stylesheet>
  
  
  
  1.1                  xml-forrest/src/core/context/skins/tigris-style/xslt/html/document2html.xsl
  
  Index: document2html.xsl
  ===================================================================
  <?xml version="1.0"?>
  <!--
  This stylesheet contains the majority of templates for converting documentv11
  to HTML.  It renders XML as HTML in this form:
  
    <div class="content">
     ...
    </div>
  
  ..which site2xhtml.xsl then combines with HTML from the index (book2menu.xsl)
  and tabs (tab2menu.xsl) to generate the final HTML.
  
  $Id: document2html.xsl,v 1.1 2003/12/22 09:56:11 nicolaken Exp $
  -->
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  
    <xsl:import href="../../../common/xslt/html/document2html.xsl"/>
    
    <xsl:template match="document">
      <div class="content">
       <div id="topmodule" align="right">
        <table border="0" cellspacing="0" cellpadding="3" width="100%">
         <!-- ( ================= middle NavBar ================== ) -->
          <tr>
          <td class="tasknav" >
          <div align="left">
              <xsl:call-template name="pdflink"/>
              <xsl:call-template name="printlink"/>
              <xsl:call-template name="xmllink"/>
          </div>
          </td>
          <td id="issueid" class="tasknav">
          <div align="right">Font size:
  	          &#160;<input type="button" onclick="ndeSetTextSize('decr'); return false;"
title="Shrink text" class="smallerfont" value="-a"/>
  	          &#160;<input type="button" onclick="ndeSetTextSize('incr'); return false;"
title="Enlarge text" class="biggerfont" value="+a"/>
  	          &#160;<input type="button" onclick="ndeSetTextSize('reset'); return false;"
title="Reset text" class="resetfont" value="Reset"/>       </div>
          </td>
         </tr>
        </table>
       </div>
       
      <!-- ( ================= Content================== ) -->
      <div id="bodycol">
        <xsl:if test="normalize-space(header/title)!=''">
          <div id="apphead">
           <h2><em><xsl:value-of select="header/title"/></em></h2>
          </div>
        </xsl:if>
        <xsl:if test="normalize-space(header/subtitle)!=''">
          <h3><em><xsl:value-of select="header/subtitle"/></em></h3>
        </xsl:if>
  
        <div id="projecthome" class="app">
          <xsl:apply-templates select="body"/>
  
         <xsl:if test="header/authors">
          <p align="right">
            <font size="-2">
              <xsl:for-each select="header/authors/person">
                <xsl:choose>
                  <xsl:when test="position()=1">by&#160;</xsl:when>
                  <xsl:otherwise>,&#160;</xsl:otherwise>
                </xsl:choose>
                <xsl:value-of select="@name"/>
              </xsl:for-each>
            </font>
          </p>
        </xsl:if>
         </div>
        </div>
      </div>
    </xsl:template>
  
    <xsl:template match="body">
  
      <xsl:if test="section and $max-depth&gt;0 and not($notoc='true') and contains($minitoc-location,'menu')">
        <toc>
          <xsl:for-each select="section">
            <tocc>
              <toca>
                <xsl:attribute name="href">
                  <xsl:text>#</xsl:text><xsl:call-template name="generate-id"/>
                </xsl:attribute>
                <xsl:value-of select="title"/>
              </toca>
              <xsl:if test="section">
                <toc2>
                  <xsl:for-each select="section">
                    <tocc>
                      <toca>
                        <xsl:attribute name="href">
                          <xsl:text>#</xsl:text><xsl:call-template name="generate-id"/>
                        </xsl:attribute>
                        <xsl:value-of select="title"/>
                      </toca>
                    </tocc>
                  </xsl:for-each>
                </toc2>
              </xsl:if>
            </tocc>
          </xsl:for-each>
        </toc>
      </xsl:if>
      
     <xsl:if test="$max-depth&gt;0 and not($notoc='true') and contains($minitoc-location,'page')"
>
        <xsl:call-template name="minitoc">
          <xsl:with-param name="tocroot" select="."/>
          <xsl:with-param name="depth">1</xsl:with-param>
        </xsl:call-template>
      </xsl:if>
      <xsl:apply-templates/>
    </xsl:template>
  
    <xsl:template name="generate-id">
      <xsl:choose>
        <xsl:when test="@id">
          <xsl:value-of select="@id"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="generate-id(.)"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>
  
    <xsl:template match="@id">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="section">
      <a name="{generate-id()}"/>
      <xsl:apply-templates select="@id"/>
  
      <xsl:variable name = "level" select = "count(ancestor::section)+1" />
  
      <xsl:choose>
        <xsl:when test="$level=1">
         <div class="h3">
          <h3><xsl:value-of select="title"/></h3>
          <xsl:apply-templates/>
        </div>  
        </xsl:when>
        <xsl:when test="$level=2">
         <div class="h4">
          <h4><xsl:value-of select="title"/></h4>
          <xsl:apply-templates select="*[not(self::title)]"/>
        </div>  
  
        </xsl:when>
        <!-- If a faq, answer sections will be level 3 (1=Q/A, 2=part) -->
        <xsl:when test="$level=3 and $notoc='true'">
          <h4 class="faq"><xsl:value-of select="title"/></h4>
          <div align="right"><a href="#{@id}-menu">^</a></div>
          <div style="margin-left: 15px">
            <xsl:apply-templates select="*[not(self::title)]"/>
          </div>
        </xsl:when>
        <xsl:when test="$level=3">
          <h4><xsl:value-of select="title"/></h4>
          <xsl:apply-templates select="*[not(self::title)]"/>
  
        </xsl:when>
  
        <xsl:otherwise>
          <h5><xsl:value-of select="title"/></h5>
          <xsl:apply-templates select="*[not(self::title)]"/>
        </xsl:otherwise>
      </xsl:choose>
  
    </xsl:template>  
  
    <xsl:template match="fixme | note | warning">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="link">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="jump">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="fork">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="p[@xml:space='preserve']">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="source">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="anchor">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="icon">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="code">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="figure">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="table">
      <xsl:apply-imports/>
    </xsl:template>
  
    <xsl:template match="title">
      <!-- do not show title elements, they are already in other places-->
    </xsl:template>
  
    <!-- Generates the PDF link -->
    <xsl:template name="pdflink">
      <xsl:if test="$dynamic-page='false'">
        <xsl:if test="not($config/disable-pdf-link) or $disable-pdf-link = 'false'">

          <a href="{$filename-noext}.pdf"><img border="0" src="{$skin-img-dir}/pdfdoc.gif"
alt="PDF"/> PDF</a>
        </xsl:if>
      </xsl:if>
    </xsl:template>
    
      <!-- Generates the XML link -->
    <xsl:template name="xmllink">
      <xsl:if test="$dynamic-page='false'">
        <xsl:if test="$disable-xml-link = 'false'">
          <a href="{$filename-noext}.xml"><img border="0" src="{$skin-img-dir}/xmldoc.gif"
alt="xml"/> xml</a>
        </xsl:if>
      </xsl:if>
    </xsl:template>
    
      <!-- Generates the "printer friendly version" link -->
    <xsl:template name="printlink">
      <xsl:if test="$disable-print-link = 'false'"> 
  <script type="text/javascript" language="Javascript">
  function printit() {  
  if (window.print) {
      window.print() ;  
  } else {
      var WebBrowser = '&lt;OBJECT ID="WebBrowser1" WIDTH="0" HEIGHT="0" CLASSID="CLSID:8856F961-340A-11D0-A96B-00C04FD705A2">&lt;/OBJECT>';
  document.body.insertAdjacentHTML('beforeEnd', WebBrowser);
      WebBrowser1.ExecWB(6, 2);//Use a 1 vs. a 2 for a prompting dialog box    WebBrowser1.outerHTML
= "";  
  }
  }
  </script>
  
  <script type="text/javascript" language="Javascript">
  var NS = (navigator.appName == "Netscape");
  var VERSION = parseInt(navigator.appVersion);
  if (VERSION > 3) {
      document.write('  <a href="javascript:printit()">');
      document.write('    <img border="0"  src="{$skin-img-dir}/printer.gif" alt="Print
this Page"/>');
      document.write('  print</a>');
  }
  </script>
  
      </xsl:if>
    </xsl:template>
    
  </xsl:stylesheet>
  
  
  
  1.1                  xml-forrest/src/core/context/skins/tigris-style/xslt/html/site2xhtml.xsl
  
  Index: site2xhtml.xsl
  ===================================================================
  <?xml version="1.0"?>
  <!--
  site2xhtml.xsl is the final stage in HTML page production.  It merges HTML from
  document2html.xsl, tab2menu.xsl and book2menu.xsl, and adds the site header,
  footer, searchbar, css etc.  As input, it takes XML of the form:
  
  <site>
    <? class="menu">
      ...
    </?>
    <? class="tab">
      ...
    </?>
    <? class="content">
      ...
    </?>
  </site>
  
  $Id: site2xhtml.xsl,v 1.1 2003/12/22 09:56:11 nicolaken Exp $
  -->
  
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  
    <xsl:import href="../../../common/xslt/html/site2xhtml.xsl"/>
    
    <xsl:template match="site">
      <html>
        <head>
          <style type="text/css">
            /* <![CDATA[ */ 
            @import "]]><xsl:value-of select="$root"/><![CDATA[skin/tigris.css";
 
            @import "]]><xsl:value-of select="$root"/><![CDATA[skin/inst.css";

            /*  ]]> */
          </style>
          <link rel="stylesheet" type="text/css" href="{$root}skin/print.css" media="print"
/>
          <script src="{$root}skin/tigris.js" type="text/javascript"></script>
          <script type="text/javascript" language="javascript" src="{$root}skin/fontsize.js"></script>
          <script type="text/javascript" language="javascript" src="{$root}skin/menu.js"></script>
          <title><xsl:value-of select="div[@class='content']/table/tr/td/h1"/></title>
          <meta http-equiv="Content-type" content="text/html" />
          <meta http-equiv="Content-style-type" content="text/css" />
        </head>
        <body onload="init();focus()" marginwidth="0" marginheight="0" class="composite">
          <script type="text/javascript">ndeSetTextSize();</script>
  
          <!--
            +=========================+
            |       topstrip          |
            +=========================+
            |                         |
            |       centerstrip       |
            |                         |
            |                         |
            +=========================+
            |       bottomstrip       |
            +=========================+
          -->
          
          <xsl:call-template name = "topstrip" />
  
          <xsl:call-template name="centerstrip"/>
  
          <xsl:call-template name="bottomstrip"/>
          
        </body>
      </html>
    </xsl:template>
  
    <xsl:template name="topstrip">
      <!--   
          +======================================================+
          |+============+    +==============+    | search box |  |
          || group logo |    | project logo |    +============+  |
          |+============+    +==============+                    |
          +======================================================+
          ||tab|tab|tab|                           publish date  |
          +======================================================+
      -->
      
      <div id="banner">   
        <table border="0" cellspacing="0" cellpadding="8" width="100%">
         <tr>
         <!-- ( ================= Group Logo ================== ) -->
          <td align="left" >
            <xsl:if test="$config/group-url">
              <div><!--<div id="cn">-->
              <xsl:call-template name="renderlogo">
                <xsl:with-param name="name" select="$config/group-name"/>
                <xsl:with-param name="url" select="$config/group-url"/>
                <xsl:with-param name="logo" select="$config/group-logo"/>
                <xsl:with-param name="root" select="$root"/>
              </xsl:call-template>
              </div>
              <span class="alt"><xsl:value-of select="$config/group-name"/></span>
            </xsl:if>
          </td>
                 
  
          <!-- ( ================= Project Logo ================== ) -->
          <td align="center" >
           <xsl:if test="$config/project-url">
             <div><!--<div id="sc">-->
              <xsl:call-template name="renderlogo">
                <xsl:with-param name="name" select="$config/project-name"/>
                <xsl:with-param name="url" select="$config/project-url"/>
                <xsl:with-param name="logo" select="$config/project-logo"/>
                <xsl:with-param name="root" select="$root"/>
              </xsl:call-template>
            </div>
            </xsl:if>        </td>
          
          <!-- ( =================  Search ================== ) -->        
          <td align="right" valign="top">
            <xsl:if test="not($config/disable-search) or
              $config/disable-search='false' and $config/searchsite-domain and
              $config/searchsite-name">
              <div id="login" align="right" class="right">
               <form method="get" action="http://www.google.com/search" target="_blank">
                 <input type="hidden" name="sitesearch" value="{$config/searchsite-domain}"/>
                 <select name="go">
                   <option value="foo">Search...</option>
       
                   <option value="site">The <xsl:value-of select="$config/searchsite-name"/>
site</option>
                   <option value="web">The web</option>
                 </select> for 
                 <input type="text" id="query" name="q" size="15"/> 
                 <input type="submit" value="Go" name="Search"/>
               </form>
            </div>
           </xsl:if>
          </td>       
         </tr>   
        </table>  
       </div>
  
        <!-- ( ================= Tabs ================== ) -->
        <xsl:apply-templates select="div[@class='tabs']"/>
  
    <div id="breadcrumbs">
      <xsl:call-template name="breadcrumbs"/>
    </div>
  
    </xsl:template>
    
    <xsl:template name="centerstrip" >
     <!--
       +=========+======================+
       |         |                      |
       |         |                      |
       |         |                      |
       |         |                      |
       |  menu   |   mainarea           |
       |         |                      |
       |         |                      |
       |         |                      |
       |         |                      |
       +=========+======================+
      -->
      <table border="0" cellspacing="0" cellpadding="4" width="100%" id="main">
        <tr valign="top">
          <!-- ( =================  Menu  ================== ) -->
          <td id="leftcol" width="20%">
            <!-- If we have any menu items, draw a menu -->
            <xsl:if test="div[@class='menu']">
              <xsl:call-template name="menu"/>
            </xsl:if>
            <div class="strut">&#160;</div>
          </td>
          <!-- ( =================  Main Area  ================== ) -->
          <!--<td valign="top" width="100%">-->
          <td>
             <xsl:call-template name="mainarea"/>
          </td>
        </tr>
      </table>
    </xsl:template>
  
    <xsl:template name="menu">
      <div id="navcolumn">
      <!--
      projecttools
      admfun
      searchbox
      helptext
      -->
      <!-- ( ================= start Menu items ================== ) -->
      <div id="projecttools" class="toolgroup">
        <div class="label">
          <strong>Section</strong>
        </div>
        <xsl:apply-templates select="div[@class='menu']"/>
        
        <xsl:if test="//toc/tocc">
          <div class="label">
             <strong>Page</strong>
          </div>
          <div class="body">
            <xsl:for-each select = "//toc/tocc">
              <div>
                <xsl:choose>
                  <xsl:when test="string-length(toca)>15">
                    <a href="{toca/@href}" title="{toca}"><xsl:value-of select="substring(toca,0,20)"
/>...</a>
                  </xsl:when>
                  <xsl:otherwise>
                    <a href="{toca/@href}"><xsl:value-of select="toca" /></a>
                  </xsl:otherwise>
                </xsl:choose>
                <xsl:if test="toc2/tocc"><!-- discard second level --></xsl:if>
              </div>
            </xsl:for-each>
          </div>     
        </xsl:if>
      </div>
      <!-- ( ================= end Menu items ================== ) -->
      
      <form action="" method="get">
        <div id="searchbox" class="toolgroup">
         <div class="label"><strong>Search</strong></div>
         <div class="body">
          <div>
          <select name="scope">
  
           <option value="projectAndSubs" selected="selected">This project</option>
           <option value="myprojects">My projects</option>
           <option value="domain" >All projects</option>
          </select>
         </div>
         <div>
          <input type="hidden" name="resultsPerPage" value="40" /> 
          <input type="text" name="query" size="10" /> 
          <input type="submit" name="Button" value="Go" />
  
         </div>
         <div><a href="#">Advanced search</a>    </div>
        </div>
       </div>
       </form>
   
      
   	<xsl:if test="$filename = 'index.html' and $config/credits">
        <div id="admfun" class="toolgroup">
          <div class="label">
           <strong>Credits</strong>
          </div>
          <div class="body">
  
          
      <table>
  		        <xsl:for-each select="$config/credits/credit[not(@role='pdf')]">
  		          <xsl:variable name="name" select="name"/>
  		          <xsl:variable name="url" select="url"/>
  		          <xsl:variable name="image" select="image"/>
  		          <xsl:variable name="width" select="width"/>
  		          <xsl:variable name="height" select="height"/>
  		          <tr> 
  		            <td></td>
  		            <td colspan="4" height="5" class="logos">
  		              <a href="{$url}">
  		                <img alt="{$name} logo" border="0">
  		                  <xsl:attribute name="src">
  		                    <xsl:if test="not(starts-with($image, 'http://'))"><xsl:value-of
select="$root"/></xsl:if>
  		                    <xsl:value-of select="$image"/>
  		                  </xsl:attribute>
  		                  <xsl:if test="$width"><xsl:attribute name="width"><xsl:value-of
select="$width"/></xsl:attribute></xsl:if>
  		                  <xsl:if test="$height"><xsl:attribute name="height"><xsl:value-of
select="$height"/></xsl:attribute></xsl:if>
  		                </img>
  		              </a>
  		            </td>
  		          </tr> 
  		        </xsl:for-each>
              </table>         
          </div>
        </div>
      </xsl:if>      
    </div>
  
    </xsl:template>
   
    <xsl:template name="mainarea">
        <xsl:apply-templates select="div[@class='content']"/>
    </xsl:template>
    
    <xsl:template name="bottomstrip">
      <!-- ( ================= start Footer ================== ) -->
    <div id="footer">
     <table border="0" cellspacing="0" cellpadding="4">
      <tr>
       <td><xsl:if test="$config/host-logo and not($config/host-logo = '')">
              <xsl:call-template name="renderlogo">
                <xsl:with-param name="name" select="$config/host-name"/>
                <xsl:with-param name="url" select="$config/host-url"/>
                <xsl:with-param name="logo" select="$config/host-logo"/>
                <xsl:with-param name="root" select="$root"/>
              </xsl:call-template>
          </xsl:if></td>
       <td>
           Copyright &#169;
              <xsl:value-of select="$config/year"/>&#160;<xsl:value-of
                select="$config/vendor"/> All rights reserved.
              <br/><script language="JavaScript" type="text/javascript"><![CDATA[<!--
                document.write(" - "+"Last Published: " + document.lastModified);
                //  -->]]></script>
       </td>
      <td align="right" nowrap="nowrap">
            <xsl:call-template name="compliancy-logos"/>
            <xsl:call-template name="bottom-credit-icons"/>              
      </td>
      </tr>
     </table>
    </div>
     <!-- ( ================= end Footer ================== ) -->
    </xsl:template>
      
    <xsl:template name="bottom-credit-icons">
        <!-- old place where to put credits icons-->
        <!--
        <xsl:if test="$filename = 'index.html' and $config/credits">
          <xsl:for-each select="$config/credits/credit[not(@role='pdf')]">
            <xsl:variable name="name" select="name"/>
            <xsl:variable name="url" select="url"/>
            <xsl:variable name="image" select="image"/>
            <xsl:variable name="width" select="width"/>
            <xsl:variable name="height" select="height"/>
            <a href="{$url}">
              <img alt="{$name} logo" border="0">
                <xsl:attribute name="src">
                  <xsl:if test="not(starts-with($image, 'http://'))"><xsl:value-of
select="$root"/></xsl:if>
                  <xsl:value-of select="$image"/>
                </xsl:attribute>
                <xsl:if test="$width"><xsl:attribute name="width"><xsl:value-of
select="$width"/></xsl:attribute></xsl:if>
                <xsl:if test="$height"><xsl:attribute name="height"><xsl:value-of
select="$height"/></xsl:attribute></xsl:if>
              </img>
            </a>
          </xsl:for-each>
        </xsl:if>
        -->
    </xsl:template>
    
    <xsl:template match="node()|@*" priority="-1">
      <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:apply-templates/>
      </xsl:copy>
    </xsl:template>
  
  </xsl:stylesheet>
  
  
  
  1.1                  xml-forrest/src/core/context/skins/tigris-style/xslt/html/tab2menu.xsl
  
  Index: tab2menu.xsl
  ===================================================================
  <?xml version="1.0"?>
  <!--
  This stylesheet generates 'tabs' at the top left of the Forrest skin.  Tabs are
  visual indicators that a certain subsection of the URI space is being browsed.
  For example, if we had tabs with paths:
  
  Tab1:  ''
  Tab2:  'community'
  Tab3:  'community/howto'
  Tab4:  'community/howto/xmlform/index.html'
  
  Then if the current path was 'community/howto/foo', Tab3 would be highlighted.
  The rule is: the tab with the longest path that forms a prefix of the current
  path is enabled.
  
  The output of this stylesheet is HTML of the form:
      <div class="tab">
        ...
      </div>
  
  which is then merged by site2xhtml.xsl
  
  $Id: tab2menu.xsl,v 1.1 2003/12/22 09:56:11 nicolaken Exp $
  -->
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  
    <xsl:import href="../../../common/xslt/html/tab2menu.xsl"/>
    
    <xsl:template match="tabs">
      <div class="tabs" id="toptabs">
       <table cellpadding="4" cellspacing="0" border="0">
         <tr>
            <xsl:call-template name="base-tabs"/>
          </tr>
        </table>
      </div>  
    </xsl:template>
  
    <xsl:template name="pre-separator">
    </xsl:template>
  
    <xsl:template name="post-separator">
    </xsl:template>
  
    <xsl:template name="separator">
    </xsl:template>
  
    <xsl:template name="selected">
      <th>
        <xsl:call-template name="base-selected"/>
      </th>
    </xsl:template>
  
    <xsl:template name="not-selected">
      <td>        
        <xsl:call-template name="base-selected"/>
      </td>
    </xsl:template>
  
  </xsl:stylesheet>
  
  
  

Mime
View raw message