couchdb-commits mailing list archives

Site index · List index
Message view « Date » · « Thread »
Top « Date » · « Thread »
From rnew...@apache.org
Subject [34/50] git commit: Refreshing M4 libraries
Date Sun, 18 Nov 2012 16:49:46 GMT
Refreshing M4 libraries


Project: http://git-wip-us.apache.org/repos/asf/couchdb/repo
Commit: http://git-wip-us.apache.org/repos/asf/couchdb/commit/69875bfc
Tree: http://git-wip-us.apache.org/repos/asf/couchdb/tree/69875bfc
Diff: http://git-wip-us.apache.org/repos/asf/couchdb/diff/69875bfc

Branch: refs/heads/docs_tmp
Commit: 69875bfcf55b05ba47a62f7a3122418d92a9a241
Parents: ddd36ab
Author: Noah Slater <nslater@apache.org>
Authored: Sun Oct 14 00:10:06 2012 +0100
Committer: Robert Newson <rnewson@apache.org>
Committed: Sun Nov 18 00:15:30 2012 +0000

----------------------------------------------------------------------
 .gitignore             |    8 ++-
 LICENSE                |   49 ++++++++++-
 NOTICE                 |   12 ++-
 bootstrap              |    4 -
 m4/ac_check_curl.m4.gz |  Bin 944 -> 0 bytes
 m4/ac_check_icu.m4.gz  |  Bin 956 -> 0 bytes
 m4/ax_check_icu.m4     |   80 +++++++++++++++++
 m4/ax_lib_curl.m4      |   38 ++++++++
 m4/ax_python_module.m4 |   49 +++++++++++
 m4/pkg.m4              |  199 +++++++++++++++++++++++++++++++++++++++++++
 m4/pkg.m4.gz           |  Bin 2202 -> 0 bytes
 11 files changed, 426 insertions(+), 13 deletions(-)
----------------------------------------------------------------------


http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/.gitignore
----------------------------------------------------------------------
diff --git a/.gitignore b/.gitignore
index 41be6b4..308c3fe 100644
--- a/.gitignore
+++ b/.gitignore
@@ -6,7 +6,6 @@
 *.in
 *.la
 *.lo
-*.m4
 *.o
 *.orig
 *.rej
@@ -17,6 +16,8 @@
 .*
 INSTALL
 Makefile
+acinclude.m4
+aclocal.m4
 apache-couchdb-*
 autom4te.cache
 bin/.deps/
@@ -42,6 +43,11 @@ etc/init/couchdb
 etc/launchd/org.apache.couchdb.plist
 etc/logrotate.d/couchdb
 libtool
+m4/libtool.m4
+m4/ltoptions.m4
+m4/ltsugar.m4
+m4/ltversion.m4
+m4/lt~obsolete.m4
 share/doc/build/CouchDB.log
 share/doc/build/doctrees
 share/doc/build/html

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/LICENSE
----------------------------------------------------------------------
diff --git a/LICENSE b/LICENSE
index be511b1..d1812ba 100644
--- a/LICENSE
+++ b/LICENSE
@@ -201,20 +201,61 @@
   See the License for the specific language governing permissions and
   limitations under the License.
 
-
 Apache CouchDB Subcomponents
 
 The Apache CouchDB project includes a number of subcomponents with separate
 copyright notices and license terms. Your use of the code for the these
 subcomponents is subject to the terms and conditions of the following licenses.
 
-For the m4/ac_check_icu.m4 component:
+For the m4/ax_lib_curl.m4 component:
 
-  Copyright (c) 2005 Akos Maroy <darkeye@tyrell.hu>
+  Copyright (c) 2009 Francesco Salvestrini <salvestrini@users.sourceforge.net>
 
   Copying and distribution of this file, with or without modification, are
   permitted in any medium without royalty provided the copyright notice
-  and this notice are preserved.
+  and this notice are preserved. This file is offered as-is, without any
+  warranty.
+
+For the m4/ax_check_icu.m4 component:
+
+  Copyright (c) 2008 Akos Maroy <darkeye@tyrell.hu>
+
+  Copying and distribution of this file, with or without modification, are
+  permitted in any medium without royalty provided the copyright notice
+  and this notice are preserved. This file is offered as-is, without any
+  warranty.
+
+For the m4/ax_python_module.m4 component:
+
+  Copyright (c) 2008 Andrew Collier <colliera@ukzn.ac.za>
+
+  Copying and distribution of this file, with or without modification, are
+  permitted in any medium without royalty provided the copyright notice
+  and this notice are preserved. This file is offered as-is, without any
+  warranty.
+  
+For the m4/pkg.m4 component:
+
+  Copyright (c) 2004 Scott James Remnant <scott@netsplit.com>.
+
+  This program is free software; you can redistribute it and/or modify
+  it under the terms of the GNU General Public License as published by
+  the Free Software Foundation; either version 2 of the License, or
+  (at your option) any later version.
+
+  This program is distributed in the hope that it will be useful, but
+  WITHOUT ANY WARRANTY; without even the implied warranty of
+  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+  General Public License for more details.
+ 
+  You should have received a copy of the GNU General Public License
+  along with this program; if not, write to the Free Software
+  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+ 
+  As a special exception to the GNU General Public License, if you
+  distribute this file as part of a program that contains a
+  configuration script generated by Autoconf, you may include it under
+  the same distribution terms that you use for the rest of that program.
 
 For the share/www/script/jquery.js component:
 

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/NOTICE
----------------------------------------------------------------------
diff --git a/NOTICE b/NOTICE
index ef3ff9e..f4ca3c6 100644
--- a/NOTICE
+++ b/NOTICE
@@ -6,15 +6,19 @@ The Apache Software Foundation (http://www.apache.org/).
 
 This product also includes the following third-party components:
 
- * ac_check_icu.m4 (http://autoconf-archive.cryp.to/ac_check_icu.html)
+ * ax_lib_curl.m4 (http://www.gnu.org/software/autoconf-archive/ax_lib_curl.html)
 
-   Copyright 2008, Akos Maroy <darkeye@tyrell.hu>
+   Copyright 2009, Francesco Salvestrini <salvestrini@users.sourceforge.net>
 
- * ac_check_curl.m4 (http://autoconf-archive.cryp.to/ac_check_curl.html)
+ * ax_check_icu.m4 (http://www.gnu.org/software/autoconf-archive/ax_check_icu.html)
 
    Copyright 2008, Akos Maroy <darkeye@tyrell.hu>
 
- * pkg.m4 (http://http://pkg-config.freedesktop.org/wiki/)
+ * ax_python_module.m4 (http://www.gnu.org/software/autoconf-archive/ax_python_module.html)
+
+   Copyright 2008, Andrew Collier <colliera@ukzn.ac.za>
+
+ * pkg.m4 (http://pkg-config.freedesktop.org/wiki/)
 
    Copyright 2004, Scott James Remnant <scott@netsplit.com>
 

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/bootstrap
----------------------------------------------------------------------
diff --git a/bootstrap b/bootstrap
index 1a96ca6..816339e 100755
--- a/bootstrap
+++ b/bootstrap
@@ -45,10 +45,6 @@ else
     sed "s/%release%/$REVISION/" < acinclude.m4.in > acinclude.m4
 fi
 
-gunzip -c m4/ac_check_icu.m4.gz > m4/ac_check_icu.m4
-gunzip -c m4/ac_check_curl.m4.gz > m4/ac_check_curl.m4
-gunzip -c m4/pkg.m4.gz > m4/pkg.m4
-
 # Seach a list of names for the first occurence of a program.
 # Some systems may use aclocal-1.10, others may have aclocal etc.
 #

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/ac_check_curl.m4.gz
----------------------------------------------------------------------
diff --git a/m4/ac_check_curl.m4.gz b/m4/ac_check_curl.m4.gz
deleted file mode 100644
index 020e646..0000000
Binary files a/m4/ac_check_curl.m4.gz and /dev/null differ

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/ac_check_icu.m4.gz
----------------------------------------------------------------------
diff --git a/m4/ac_check_icu.m4.gz b/m4/ac_check_icu.m4.gz
deleted file mode 100644
index 8af50ff..0000000
Binary files a/m4/ac_check_icu.m4.gz and /dev/null differ

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/ax_check_icu.m4
----------------------------------------------------------------------
diff --git a/m4/ax_check_icu.m4 b/m4/ax_check_icu.m4
new file mode 100644
index 0000000..f30de16
--- /dev/null
+++ b/m4/ax_check_icu.m4
@@ -0,0 +1,80 @@
+# ===========================================================================
+#       http://www.gnu.org/software/autoconf-archive/ax_check_icu.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_CHECK_ICU(version, action-if, action-if-not)
+#
+# DESCRIPTION
+#
+#   Defines ICU_LIBS, ICU_CFLAGS, ICU_CXXFLAGS. See icu-config(1) man page.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Akos Maroy <darkeye@tyrell.hu>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 6
+
+AU_ALIAS([AC_CHECK_ICU], [AX_CHECK_ICU])
+AC_DEFUN([AX_CHECK_ICU], [
+  succeeded=no
+
+  if test -z "$ICU_CONFIG"; then
+    AC_PATH_PROG(ICU_CONFIG, icu-config, no)
+  fi
+
+  if test "$ICU_CONFIG" = "no" ; then
+    echo "*** The icu-config script could not be found. Make sure it is"
+    echo "*** in your path, and that taglib is properly installed."
+    echo "*** Or see http://ibm.com/software/globalization/icu/"
+  else
+    ICU_VERSION=`$ICU_CONFIG --version`
+    AC_MSG_CHECKING(for ICU >= $1)
+        VERSION_CHECK=`expr $ICU_VERSION \>\= $1`
+        if test "$VERSION_CHECK" = "1" ; then
+            AC_MSG_RESULT(yes)
+            succeeded=yes
+
+            AC_MSG_CHECKING(ICU_CPPFLAGS)
+            ICU_CPPFLAGS=`$ICU_CONFIG --cppflags`
+            AC_MSG_RESULT($ICU_CPPFLAGS)
+
+            AC_MSG_CHECKING(ICU_CFLAGS)
+            ICU_CFLAGS=`$ICU_CONFIG --cflags`
+            AC_MSG_RESULT($ICU_CFLAGS)
+
+            AC_MSG_CHECKING(ICU_CXXFLAGS)
+            ICU_CXXFLAGS=`$ICU_CONFIG --cxxflags`
+            AC_MSG_RESULT($ICU_CXXFLAGS)
+
+            AC_MSG_CHECKING(ICU_LIBS)
+            ICU_LIBS=`$ICU_CONFIG --ldflags`
+            AC_MSG_RESULT($ICU_LIBS)
+        else
+            ICU_CPPFLAGS=""
+            ICU_CFLAGS=""
+            ICU_CXXFLAGS=""
+            ICU_LIBS=""
+            ## If we have a custom action on failure, don't print errors, but
+            ## do set a variable so people can do so.
+            ifelse([$3], ,echo "can't find ICU >= $1",)
+        fi
+
+        AC_SUBST(ICU_CPPFLAGS)
+        AC_SUBST(ICU_CFLAGS)
+        AC_SUBST(ICU_CXXFLAGS)
+        AC_SUBST(ICU_LIBS)
+  fi
+
+  if test $succeeded = yes; then
+     ifelse([$2], , :, [$2])
+  else
+     ifelse([$3], , AC_MSG_ERROR([Library requirements (ICU) not met.]), [$3])
+  fi
+])

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/ax_lib_curl.m4
----------------------------------------------------------------------
diff --git a/m4/ax_lib_curl.m4 b/m4/ax_lib_curl.m4
new file mode 100644
index 0000000..0dd5df0
--- /dev/null
+++ b/m4/ax_lib_curl.m4
@@ -0,0 +1,38 @@
+# ===========================================================================
+#        http://www.gnu.org/software/autoconf-archive/ax_lib_curl.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_LIB_CURL([VERSION],[ACTION-IF-SUCCESS],[ACTION-IF-FAILURE])
+#
+# DESCRIPTION
+#
+#   Checks for minimum curl library version VERSION. If successfull executes
+#   ACTION-IF-SUCCESS otherwise ACTION-IF-FAILURE.
+#
+#   Defines CURL_LIBS and CURL_CFLAGS.
+#
+#   A simple example:
+#
+#     AX_LIB_CURL([7.19.4],,[
+#       AC_MSG_ERROR([Your system lacks of libcurl >= 7.19.4])
+#     ])
+#
+#   This macro is a rearranged version of AC_LIB_CURL from Akos Maroy.
+#
+# LICENSE
+#
+#   Copyright (c) 2009 Francesco Salvestrini <salvestrini@users.sourceforge.net>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 7
+
+AU_ALIAS([AC_CHECK_CURL], [AX_LIB_CURL])
+AC_DEFUN([AX_LIB_CURL], [
+  AX_PATH_GENERIC([curl],[$1],'s/^libcurl\ \+//',[$2],[$3])
+])

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/ax_python_module.m4
----------------------------------------------------------------------
diff --git a/m4/ax_python_module.m4 b/m4/ax_python_module.m4
new file mode 100644
index 0000000..bd70a06
--- /dev/null
+++ b/m4/ax_python_module.m4
@@ -0,0 +1,49 @@
+# ===========================================================================
+#     http://www.gnu.org/software/autoconf-archive/ax_python_module.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PYTHON_MODULE(modname[, fatal])
+#
+# DESCRIPTION
+#
+#   Checks for Python module.
+#
+#   If fatal is non-empty then absence of a module will trigger an error.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Andrew Collier <colliera@ukzn.ac.za>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 5
+
+AU_ALIAS([AC_PYTHON_MODULE], [AX_PYTHON_MODULE])
+AC_DEFUN([AX_PYTHON_MODULE],[
+    if test -z $PYTHON;
+    then
+        PYTHON="python"
+    fi
+    PYTHON_NAME=`basename $PYTHON`
+    AC_MSG_CHECKING($PYTHON_NAME module: $1)
+	$PYTHON -c "import $1" 2>/dev/null
+	if test $? -eq 0;
+	then
+		AC_MSG_RESULT(yes)
+		eval AS_TR_CPP(HAVE_PYMOD_$1)=yes
+	else
+		AC_MSG_RESULT(no)
+		eval AS_TR_CPP(HAVE_PYMOD_$1)=no
+		#
+		if test -n "$2"
+		then
+			AC_MSG_ERROR(failed to find required module $1)
+			exit 1
+		fi
+	fi
+])

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/pkg.m4
----------------------------------------------------------------------
diff --git a/m4/pkg.m4 b/m4/pkg.m4
new file mode 100644
index 0000000..f26f84c
--- /dev/null
+++ b/m4/pkg.m4
@@ -0,0 +1,199 @@
+# pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
+# serial 1 (pkg-config-0.24)
+# 
+# Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+#
+# As a special exception to the GNU General Public License, if you
+# distribute this file as part of a program that contains a
+# configuration script generated by Autoconf, you may include it under
+# the same distribution terms that you use for the rest of that program.
+
+# PKG_PROG_PKG_CONFIG([MIN-VERSION])
+# ----------------------------------
+AC_DEFUN([PKG_PROG_PKG_CONFIG],
+[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
+m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$])
+m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$])
+AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])
+AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path])
+AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path])
+
+if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
+	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
+fi
+if test -n "$PKG_CONFIG"; then
+	_pkg_min_version=m4_default([$1], [0.9.0])
+	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
+	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
+		AC_MSG_RESULT([yes])
+	else
+		AC_MSG_RESULT([no])
+		PKG_CONFIG=""
+	fi
+fi[]dnl
+])# PKG_PROG_PKG_CONFIG
+
+# PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+#
+# Check to see whether a particular set of modules exists.  Similar
+# to PKG_CHECK_MODULES(), but does not set variables or print errors.
+#
+# Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+# only at the first occurence in configure.ac, so if the first place
+# it's called might be skipped (such as if it is within an "if", you
+# have to call PKG_CHECK_EXISTS manually
+# --------------------------------------------------------------
+AC_DEFUN([PKG_CHECK_EXISTS],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+if test -n "$PKG_CONFIG" && \
+    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
+  m4_default([$2], [:])
+m4_ifvaln([$3], [else
+  $3])dnl
+fi])
+
+# _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
+# ---------------------------------------------
+m4_define([_PKG_CONFIG],
+[if test -n "$$1"; then
+    pkg_cv_[]$1="$$1"
+ elif test -n "$PKG_CONFIG"; then
+    PKG_CHECK_EXISTS([$3],
+                     [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`
+		      test "x$?" != "x0" && pkg_failed=yes ],
+		     [pkg_failed=yes])
+ else
+    pkg_failed=untried
+fi[]dnl
+])# _PKG_CONFIG
+
+# _PKG_SHORT_ERRORS_SUPPORTED
+# -----------------------------
+AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
+        _pkg_short_errors_supported=yes
+else
+        _pkg_short_errors_supported=no
+fi[]dnl
+])# _PKG_SHORT_ERRORS_SUPPORTED
+
+
+# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
+# [ACTION-IF-NOT-FOUND])
+#
+#
+# Note that if there is a possibility the first call to
+# PKG_CHECK_MODULES might not happen, you should be sure to include an
+# explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
+#
+#
+# --------------------------------------------------------------
+AC_DEFUN([PKG_CHECK_MODULES],
+[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
+AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
+AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
+
+pkg_failed=no
+AC_MSG_CHECKING([for $1])
+
+_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
+_PKG_CONFIG([$1][_LIBS], [libs], [$2])
+
+m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
+and $1[]_LIBS to avoid the need to call pkg-config.
+See the pkg-config man page for more details.])
+
+if test $pkg_failed = yes; then
+   	AC_MSG_RESULT([no])
+        _PKG_SHORT_ERRORS_SUPPORTED
+        if test $_pkg_short_errors_supported = yes; then
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2"
2>&1`
+        else 
+	        $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1`
+        fi
+	# Put the nasty error message in config.log where it belongs
+	echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
+
+	m4_default([$4], [AC_MSG_ERROR(
+[Package requirements ($2) were not met:
+
+$$1_PKG_ERRORS
+
+Consider adjusting the PKG_CONFIG_PATH environment variable if you
+installed software in a non-standard prefix.
+
+_PKG_TEXT])[]dnl
+        ])
+elif test $pkg_failed = untried; then
+     	AC_MSG_RESULT([no])
+	m4_default([$4], [AC_MSG_FAILURE(
+[The pkg-config script could not be found or is too old.  Make sure it
+is in your PATH or set the PKG_CONFIG environment variable to the full
+path to pkg-config.
+
+_PKG_TEXT
+
+To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl
+        ])
+else
+	$1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
+	$1[]_LIBS=$pkg_cv_[]$1[]_LIBS
+        AC_MSG_RESULT([yes])
+	$3
+fi[]dnl
+])# PKG_CHECK_MODULES
+
+
+# PKG_INSTALLDIR(DIRECTORY)
+# -------------------------
+# Substitutes the variable pkgconfigdir as the location where a module
+# should install pkg-config .pc files. By default the directory is
+# $libdir/pkgconfig, but the default can be changed by passing
+# DIRECTORY. The user can override through the --with-pkgconfigdir
+# parameter.
+AC_DEFUN([PKG_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${libdir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([pkgconfigdir],
+    [AS_HELP_STRING([--with-pkgconfigdir], pkg_description)],,
+    [with_pkgconfigdir=]pkg_default)
+AC_SUBST([pkgconfigdir], [$with_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+]) dnl PKG_INSTALLDIR
+
+
+# PKG_NOARCH_INSTALLDIR(DIRECTORY)
+# -------------------------
+# Substitutes the variable noarch_pkgconfigdir as the location where a
+# module should install arch-independent pkg-config .pc files. By
+# default the directory is $datadir/pkgconfig, but the default can be
+# changed by passing DIRECTORY. The user can override through the
+# --with-noarch-pkgconfigdir parameter.
+AC_DEFUN([PKG_NOARCH_INSTALLDIR],
+[m4_pushdef([pkg_default], [m4_default([$1], ['${datadir}/pkgconfig'])])
+m4_pushdef([pkg_description],
+    [pkg-config arch-independent installation directory @<:@]pkg_default[@:>@])
+AC_ARG_WITH([noarch-pkgconfigdir],
+    [AS_HELP_STRING([--with-noarch-pkgconfigdir], pkg_description)],,
+    [with_noarch_pkgconfigdir=]pkg_default)
+AC_SUBST([noarch_pkgconfigdir], [$with_noarch_pkgconfigdir])
+m4_popdef([pkg_default])
+m4_popdef([pkg_description])
+]) dnl PKG_NOARCH_INSTALLDIR

http://git-wip-us.apache.org/repos/asf/couchdb/blob/69875bfc/m4/pkg.m4.gz
----------------------------------------------------------------------
diff --git a/m4/pkg.m4.gz b/m4/pkg.m4.gz
deleted file mode 100644
index 08b9e6b..0000000
Binary files a/m4/pkg.m4.gz and /dev/null differ


Mime
View raw message