cocoon-cvs mailing list archives

Site index · List index
Message view « Date » · « Thread »
Top « Date » · « Thread »
From jheym...@apache.org
Subject svn commit: r330548 [132/132] - in /cocoon/whiteboard/maven2/cocoon-flat-layout: ./ cocoon-ajax-block/ cocoon-ajax-block/api/ cocoon-ajax-block/api/src/ cocoon-ajax-block/api/src/main/ cocoon-ajax-block/api/src/main/java/ cocoon-ajax-block/api/src/main...
Date Thu, 03 Nov 2005 14:00:48 GMT
Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/sitemap2html.xslt
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/sitemap2html.xslt?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/sitemap2html.xslt (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/sitemap2html.xslt Thu Nov  3 05:41:06 2005
@@ -0,0 +1,497 @@
+<?xml version="1.0"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!-- CVS $Id: sitemap2html.xslt,v 1.3 2004/03/06 02:25:41 antonio Exp $ -->
+
+<xsl:stylesheet version="1.0"
+                xmlns:map="http://apache.org/cocoon/sitemap/1.0"
+                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+ <xsl:template match="/">
+  <html>
+   <head>
+    <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1"/>
+    <meta name="Author" content="{author}"/>
+    <meta name="Version" content="{version}"/>
+    <title>The Sitemap</title>
+   </head>
+   <body>
+    <xsl:apply-templates/>
+   </body>
+  </html>
+ </xsl:template>
+
+ <xsl:template match="map:sitemap">
+  <h1>The Sitemap</h1>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:components">
+  <h2>Components</h2>
+  <table border="0" width="100%" bgcolor="navy" cellspacing="0" cellpadding="0">
+   <tr>
+    <td>
+     <table border="0" width="100%" cellspacing="2" cellpadding="0">
+      <tr>
+       <td bgcolor="lightgrey">
+        <table border="0" width="100%" cellspacing="2" cellpadding="0">
+         <xsl:apply-templates select="map:generators"/>
+         <xsl:apply-templates select="map:transformers"/>
+         <xsl:apply-templates select="map:readers"/>
+         <xsl:apply-templates select="map:serializers"/>
+         <xsl:apply-templates select="map:selectors"/>
+         <xsl:apply-templates select="map:matchers"/>
+        </table>
+       </td>
+      </tr>
+     </table>
+    </td>
+   </tr>
+  </table>
+ </xsl:template>
+
+ <xsl:template match="map:views">
+  <h2>Views</h2>
+  <table border="0" width="100%" bgcolor="navy" cellspacing="0" cellpadding="0">
+   <tr>
+    <td>
+     <table border="0" width="100%" cellspacing="2" cellpadding="0">
+      <tr>
+       <td bgcolor="lightgrey">
+        <table border="0" width="100%" cellspacing="2" cellpadding="0">
+         <tr>
+          <td colspan="2" bgcolor="white"><b>Name</b></td>
+          <td bgcolor="white"><b>Arguments</b></td>
+         </tr>
+         <xsl:apply-templates select="map:match|map:select|map:redirect-to|map:generate|map:transform|map:select|map:read"/>
+        </table>
+       </td>
+      </tr>
+     </table>
+    </td>
+   </tr>
+  </table>
+ </xsl:template>
+
+ <xsl:template match="map:resources">
+  <h2>Resources</h2>
+  <table border="0" width="100%" bgcolor="navy" cellspacing="0" cellpadding="0">
+   <tr>
+    <td>
+     <table border="0" width="100%" cellspacing="2" cellpadding="0">
+      <tr>
+       <td bgcolor="lightgrey">
+        <table border="0" width="100%" cellspacing="2" cellpadding="0">
+         <tr>
+          <td colspan="3" bgcolor="white"><b>Name</b></td>
+         </tr>
+         <xsl:apply-templates/>
+        </table>
+       </td>
+      </tr>
+     </table>
+    </td>
+   </tr>
+  </table>
+ </xsl:template>
+
+ <xsl:template match="map:pipelines">
+  <h2>Pipelines</h2>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:generators">
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Generators</xsl:with-param>
+   <xsl:with-param name="comp-type">generator</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="label">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:transformers">
+  <xsl:call-template name="break"/>
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Transformers</xsl:with-param>
+   <xsl:with-param name="comp-type">transformer</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="label">true</xsl:with-param>
+   <xsl:with-param name="break">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:readers">
+  <xsl:call-template name="break"/>
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Readers</xsl:with-param>
+   <xsl:with-param name="comp-type">reader</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="break">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:serializers">
+  <xsl:call-template name="break"/>
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Serializers</xsl:with-param>
+   <xsl:with-param name="comp-type">serializer</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="break">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:selectors">
+  <xsl:call-template name="break"/>
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Selectors</xsl:with-param>
+   <xsl:with-param name="comp-type">selector</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="break">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:matchers">
+  <xsl:call-template name="break"/>
+  <xsl:call-template name="show-components">
+   <xsl:with-param name="type">Matchers</xsl:with-param>
+   <xsl:with-param name="comp-type">matcher</xsl:with-param>
+   <xsl:with-param name="default" select="@default"/>
+   <xsl:with-param name="components" select="./*"/>
+   <xsl:with-param name="break">true</xsl:with-param>
+  </xsl:call-template>
+ </xsl:template>
+
+ <xsl:template match="map:view">
+  <xsl:if test="preceding-sibling::map:view">
+   <xsl:call-template name="break"/>
+  </xsl:if>
+  <tr>
+   <td colspan="2" bgcolor="white"><a href=""><xsl:value-of select="@name"/></a></td>
+   <td bgcolor="white">generate-from="<xsl:value-of select="@generate-from"/>"</td>
+  </tr>
+  <tr>
+   <td bgcolor="white">&#160;</td>
+   <td colspan="2" bgcolor="white">
+    <xsl:apply-templates/>
+   </td>
+  </tr>
+ </xsl:template>
+
+ <xsl:template match="map:resource">
+  <xsl:if test="preceding-sibling::map:resource">
+   <xsl:call-template name="break"/>
+  </xsl:if>
+  <tr>
+   <td colspan="3" bgcolor="white"><a href=""><xsl:value-of select="@name"/></a></td>
+  </tr>
+  <tr>
+   <td bgcolor="white">&#160;</td>
+   <td colspan="2" bgcolor="white">
+    <xsl:apply-templates/>
+   </td>
+  </tr>
+ </xsl:template>
+
+ <xsl:template match="map:pipeline">
+  <table border="0" width="100%" bgcolor="navy" cellspacing="0" cellpadding="0">
+   <tr>
+    <td>
+     <table border="0" width="100%" cellspacing="2" cellpadding="0">
+      <tr>
+       <td bgcolor="lightgrey">
+        <table border="0" width="100%" cellspacing="2" cellpadding="0">
+         <xsl:apply-templates/>
+        </table>
+       </td>
+      </tr>
+     </table>
+    </td>
+   </tr>
+  </table>
+  <br/>
+ </xsl:template>
+
+ <xsl:template match="map:match">
+  <xsl:choose>
+   <xsl:when test="ancestor::*[self::map:pipeline]">
+    <tr>
+     <td bgcolor="white">
+      <xsl:call-template name="indent"/>
+      <a href="">match</a>
+      <xsl:if test="@type">
+        type="<xsl:value-of select="@type"/>"
+      </xsl:if>
+      pattern="<xsl:value-of select="@pattern"/>"
+      <br/>
+      <xsl:apply-templates/>
+     </td>
+    </tr>
+   </xsl:when>
+   <xsl:otherwise>
+    <xsl:call-template name="indent"/>
+    <a href="">match</a>
+    <xsl:if test="@type">
+      type="<xsl:value-of select="@type"/>"
+    </xsl:if>
+    pattern="<xsl:value-of select="@pattern"/>"
+    <br/>
+    <xsl:apply-templates/>
+   </xsl:otherwise>
+  </xsl:choose>
+ </xsl:template>
+
+ <xsl:template match="map:select">
+  <xsl:call-template name="indent"/>
+  <a href="">select</a>
+  <xsl:if test="@type">
+    type="<xsl:value-of select="@type"/>"
+  </xsl:if>
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:when">
+  <xsl:call-template name="indent"/>
+  <a href="">when</a> test="<xsl:value-of select="@test"/>"<br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:otherwise">
+  <xsl:call-template name="indent"/>
+  <a href="">otherwise</a><br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:generate">
+  <xsl:call-template name="indent"/>
+  <a href="">generate</a>
+  <xsl:if test="@type">
+    type="<xsl:value-of select="@type"/>"
+  </xsl:if>
+  src="<xsl:value-of select="@src"/>"
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:transform">
+  <xsl:call-template name="indent"/>
+  <a href="">transform</a>
+  <xsl:if test="@type">
+    type="<xsl:value-of select="@type"/>"
+  </xsl:if>
+  src="<xsl:value-of select="@src"/>"
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:read">
+  <xsl:call-template name="indent"/>
+  <a href="">read</a>
+  <xsl:if test="@type">
+    type="<xsl:value-of select="@type"/>"
+  </xsl:if>
+  src="<xsl:value-of select="@src"/>"
+  <xsl:if test="@mime-type">
+    mime-type="<xsl:value-of select="@mime-type"/>"
+  </xsl:if>
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:redirect-to">
+  <xsl:call-template name="indent"/>
+  <a href="">redirect-to</a>
+  <xsl:choose>
+    <xsl:when test="@uri">
+      uri="<xsl:value-of select="@uri"/>"
+    </xsl:when>
+    <xsl:when test="@resource">
+      resource="<xsl:value-of select="@resource"/>"
+    </xsl:when>
+  </xsl:choose>
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:serialize">
+  <xsl:call-template name="indent"/>
+  <a href="">serialize</a>
+  <xsl:if test="@type">
+    type="<xsl:value-of select="@type"/>"
+  </xsl:if>
+  <xsl:if test="@mime-type">
+    mime-type="<xsl:value-of select="@mime-type"/>"
+  </xsl:if>
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:mount">
+  <xsl:call-template name="indent"/>
+  <a href="">mount</a> src="<xsl:value-of select="@src"/>" uri-prefix="<xsl:value-of select="@uri-prefix"/>"<br/>
+  <xsl:if test="@check-reload">
+    check-reload="<xsl:value-of select="@check-reload"/>"
+  </xsl:if>
+  <br/>
+  <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="map:handle-errors">
+  <tr>
+   <td bgcolor="white">
+    <xsl:call-template name="indent"/>
+    <a href="">handle-errors</a>
+    <br/>
+    <xsl:apply-templates/>
+   </td>
+  </tr>
+ </xsl:template>
+
+ <!-- named templates -->
+
+ <xsl:template name="show-components">
+  <xsl:param name="type"/>
+  <xsl:param name="comp-type"/>
+  <xsl:param name="default"/>
+  <xsl:param name="components"/>
+  <xsl:param name="label"/>
+  <tr>
+   <td colspan="3" bgcolor="white">
+    <span class="h3"><xsl:value-of select="$type"/> (default=<i><xsl:value-of select="$default"/></i>)</span>
+   </td>
+  </tr>
+  <tr>
+   <td bgcolor="white"><b>Name</b></td>
+   <xsl:choose>
+    <xsl:when test="$label">
+     <td bgcolor="white"><b>Class</b></td>
+     <td bgcolor="white"><b>Label</b></td>
+    </xsl:when>
+    <xsl:otherwise>
+     <td colspan="2" bgcolor="white"><b>Class</b></td>
+    </xsl:otherwise>
+   </xsl:choose>
+  </tr>
+  <xsl:for-each select="$components">
+   <tr>
+    <td bgcolor="white"><a href="sitemap-component?component={$comp-type}&amp;name={@name}"><xsl:value-of select="@name"/></a></td>
+    <xsl:choose>
+     <xsl:when test="$label">
+      <xsl:choose>
+       <xsl:when test="@src">
+        <td bgcolor="white"><xsl:value-of select="@src"/></td>
+       </xsl:when>
+       <xsl:otherwise>
+        <td bgcolor="white"><i><xsl:value-of select="@factory"/></i></td>
+       </xsl:otherwise>
+      </xsl:choose>
+      <td bgcolor="white"><xsl:value-of select="@label"/>&#160;</td>
+     </xsl:when>
+     <xsl:otherwise>
+      <xsl:choose>
+       <xsl:when test="@src">
+        <td colspan="2" bgcolor="white"><xsl:value-of select="@src"/></td>
+       </xsl:when>
+       <xsl:otherwise>
+        <td colspan="2" bgcolor="white"><i><xsl:value-of select="@factory"/></i></td>
+       </xsl:otherwise>
+      </xsl:choose>
+     </xsl:otherwise>
+    </xsl:choose>
+   </tr>
+   <xsl:if test="./*">
+<!--
+    <xsl:call-template name="show-config"/>
+-->
+   </xsl:if>
+  </xsl:for-each>
+ </xsl:template>
+
+ <xsl:template name="show-config">
+  <xsl:param name="indent"/>
+  <xsl:choose>
+   <xsl:when test="string-length($indent)=0">
+    <tr>
+     <td align="right">Configuration</td>
+     <td colspan="3">
+      <xsl:for-each select="./*">
+       &#160;<xsl:value-of select="name()"/>
+       <xsl:if test="./*">
+        <xsl:call-template name="show-config">
+         <xsl:with-param name="indent">&#160;<xsl:value-of select="$indent"/></xsl:with-param>
+        </xsl:call-template>
+       </xsl:if>
+      </xsl:for-each>
+     </td>
+    </tr>
+   </xsl:when>
+   <xsl:otherwise>
+    <tr>
+     <td align="right">&#160;</td>
+     <td colspan="3">
+      <xsl:for-each select="./*">
+       &#160;<xsl:value-of select="name()"/>=<xsl:value-of select="text()"/>
+       <xsl:if test="./*">
+        <xsl:call-template name="show-config">
+         <xsl:with-param name="indent">&#160;<xsl:value-of select="$indent"/></xsl:with-param>
+        </xsl:call-template>
+       </xsl:if>
+      </xsl:for-each>
+     </td>
+    </tr>
+   </xsl:otherwise>
+  </xsl:choose>
+ </xsl:template>
+
+ <xsl:template name="break">
+  <tr>
+   <td colspan="3" bgcolor="white"><hr color="navy"/></td>
+  </tr>
+ </xsl:template>
+
+ <xsl:template name="indent">
+  <xsl:for-each select="ancestor::*">
+   <xsl:choose>
+    <xsl:when test="local-name(.)='pipeline'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='pipelines'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='sitemap'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='resource'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='resources'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='view'">
+    </xsl:when>
+    <xsl:when test="local-name(.)='views'">
+    </xsl:when>
+    <xsl:otherwise>
+     &#160;&#160;
+    </xsl:otherwise>
+   </xsl:choose>
+  </xsl:for-each>
+ </xsl:template>
+
+ <xsl:template match="*|@*|text()|comment()|processing-instruction()" priority="-1"/>
+
+</xsl:stylesheet>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/sitemap2html.xslt
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/status2html.xslt
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/status2html.xslt?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/status2html.xslt (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/status2html.xslt Thu Nov  3 05:41:06 2005
@@ -0,0 +1,171 @@
+<?xml version="1.0"?>
+<!--
+  Copyright 1999-2005 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!--+
+    | Converts output of the StatusGenerator into HTML page
+    | 
+    | CVS $Id: status2html.xslt,v 1.8 2004/03/06 02:25:41 antonio Exp $
+    +-->
+
+<xsl:stylesheet version="1.0"
+                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns:status="http://apache.org/cocoon/status/2.0"
+                xmlns:xalan="http://xml.apache.org/xalan"
+                exclude-result-prefixes="xalan">
+ 
+  <xsl:param name="contextPath"/>
+
+  <xsl:template match="status:statusinfo">
+    <html>
+      <head>
+        <title>Cocoon Status [<xsl:value-of select="@status:host"/>]</title>
+        <link href="{$contextPath}/styles/main.css" type="text/css" rel="stylesheet"/>
+        <script src="{$contextPath}/scripts/main.js" type="text/javascript"/>
+      </head>
+
+      <body>
+        <h1><xsl:value-of select="@status:host"/> - <xsl:value-of select="@status:date"/></h1>
+        <h2>Apache Cocoon <xsl:value-of select="@status:cocoon-version"/></h2>
+        <li>
+          <span class="description">Created:</span>
+          <xsl:text> </xsl:text>
+          <xsl:value-of select="@status:creation-time"/>
+        </li>
+        <li>
+          <span class="description">Build:</span>
+          <xsl:text> </xsl:text>
+          <xsl:value-of select="@status:build-info"/>
+        </li>
+        <xsl:apply-templates/>
+
+        <!--
+          - Add XSLT processor information
+          -->
+        <h2>XSLT Processor</h2>
+        <li>
+          <span class="description">XSLT Version:</span>
+          <xsl:text> </xsl:text>
+          <xsl:value-of select="system-property('xsl:version')"/>
+        </li>
+        <li>
+          <span class="description">Vendor:</span>
+          <xsl:text> </xsl:text>
+          <xsl:value-of select="system-property('xsl:vendor')"/>
+        </li>
+        <li>
+          <span class="description">Vendor URL:</span>
+          <xsl:text> </xsl:text>
+          <xsl:value-of select="system-property('xsl:vendor-url')"/>
+        </li>
+
+        <!--
+          - Add Xalan / Xerces information using custom Xalan extension
+          - (if it's present)
+          -->
+        <xsl:if test="function-available('xalan:checkEnvironment')">
+          <xsl:apply-templates select="xalan:checkEnvironment()"/>
+        </xsl:if>
+      </body>
+    </html>
+  </xsl:template>
+
+  <xsl:template match="status:group">
+    <h2><xsl:value-of select="@status:name"/></h2>
+    <ul><xsl:apply-templates select="status:value"/></ul>
+    <xsl:apply-templates select="status:group"/>
+    <xsl:if test="status:cont">
+    	<ul>
+    		<xsl:apply-templates select="status:cont"/>    	
+    	</ul>
+    </xsl:if>
+  </xsl:template>
+  
+  <xsl:template match="status:cont">
+  	<li>
+  		<xsl:for-each select="@*">
+  			<span class="description"><xsl:value-of select="name()"/>:<xsl:text> </xsl:text> </span><xsl:value-of select="."/>
+  			<xsl:if test="position() != last()">, </xsl:if>
+  		</xsl:for-each>
+  	</li>
+    <xsl:if test="status:cont">
+    	<ul>
+    		<xsl:apply-templates select="status:cont"/>    	
+    	</ul>  	
+    </xsl:if>
+  </xsl:template>
+
+  <xsl:template match="status:value">
+    <li>
+      <span class="description"><xsl:value-of select="@status:name"/><xsl:text>: </xsl:text></span>
+      <xsl:choose>
+        <xsl:when test="contains(@status:name,'free') or contains(@status:name,'total') or contains(@status:name,'used')">
+          <xsl:call-template name="suffix">
+            <xsl:with-param name="bytes" select="number(.)"/>
+          </xsl:call-template>
+        </xsl:when>      
+        <xsl:when test="count(status:line) &lt;= 1">
+          <xsl:value-of select="status:line"/>
+        </xsl:when>
+        <xsl:otherwise>
+          <span class="switch" id="{generate-id(.)}-switch" onclick="toggle('{generate-id(.)}')">[show]</span>
+          <ul id="{generate-id(.)}" style="display: none">
+             <xsl:apply-templates />
+          </ul>
+        </xsl:otherwise>
+      </xsl:choose>
+    </li>
+  </xsl:template>
+
+  <xsl:template match="status:line">
+    <li><xsl:value-of select="."/></li>
+  </xsl:template>
+
+  <xsl:template name="suffix">
+    <xsl:param name="bytes"/>
+    <xsl:choose>
+      <!-- More than 4 MB (=4194304) -->
+      <xsl:when test="$bytes &gt;= 4194304">
+        <xsl:value-of select="round($bytes div 10485.76) div 100"/> MB
+      </xsl:when>
+      <!-- More than 4 KB (=4096) -->
+      <xsl:when test="$bytes &gt; 4096">
+        <xsl:value-of select="round($bytes div 10.24) div 100"/> KB
+      </xsl:when>
+      <!-- Less -->
+      <xsl:otherwise>
+        <xsl:value-of select="$bytes"/> B
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+
+  <!--
+    - Process Xalan extension output
+    -->
+  <xsl:template match="checkEnvironmentExtension">
+    <h2>Xerces, Xalan</h2>
+    <ul><xsl:apply-templates select="EnvironmentCheck/environment/item[starts-with(@key, 'version.')]"/></ul>
+  </xsl:template> 
+
+  <xsl:template match="item">
+    <li style="width: 40%">
+      <span class="description"><xsl:value-of select="@key"/>:</span>
+      <xsl:text> </xsl:text>
+      <xsl:value-of select="."/>
+    </li>
+  </xsl:template> 
+   
+</xsl:stylesheet>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/status2html.xslt
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/xml2html.xslt
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/xml2html.xslt?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/xml2html.xslt (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/xml2html.xslt Thu Nov  3 05:41:06 2005
@@ -0,0 +1,201 @@
+<?xml version="1.0"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!--+
+    | XSLT REC Compliant Version of IE5 Default Stylesheet
+    |
+    | Original version by Jonathan Marsh (jmarsh@microsoft.com)
+    | Conversion to XSLT 1.0 REC Syntax by Steve Muench (smuench@oracle.com)
+    | Added script support by Andrew Timberlake (andrew@timberlake.co.za)
+    | Cleaned up and ported to standard DOM by Stefano Mazzocchi (stefano@apache.org)
+    |
+    | CVS $Id: xml2html.xslt,v 1.10 2004/05/01 13:20:55 joerg Exp $
+    +-->
+
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+   <xsl:template match="/">
+      <HTML>
+         <HEAD>
+            <link href="/styles/prettycontent.css" type="text/css" rel="stylesheet"/>
+            <script src="/scripts/prettycontent.js" type="text/javascript"/>
+         </HEAD>
+         <BODY>
+            <xsl:apply-templates/>
+         </BODY>
+      </HTML>
+   </xsl:template>
+
+   <!-- match processing instructions -->
+   <xsl:template match="processing-instruction()">
+      <DIV class="e">
+         <SPAN class="m">&lt;?</SPAN>
+         <SPAN class="pi">
+            <xsl:value-of select="name(.)"/>
+            <xsl:text> </xsl:text>
+            <xsl:value-of select="."/>
+         </SPAN>
+         <SPAN class="m">?></SPAN>
+      </DIV>
+   </xsl:template>
+
+   <!-- match text -->
+   <xsl:template match="text()">
+      <DIV class="e">
+         <SPAN class="t">
+            <xsl:value-of select="."/>
+         </SPAN>
+      </DIV>
+   </xsl:template>
+
+   <!-- match comments -->
+   <xsl:template match="comment()">
+      <DIV class="e">
+         <SPAN class="b" onclick="xml2htmlToggle(event)">-</SPAN>
+         <SPAN class="m">&lt;!--</SPAN>
+         <SPAN class="c">
+            <PRE>
+               <xsl:value-of select="."/>
+            </PRE>
+         </SPAN>
+         <SPAN class="m">--></SPAN>
+      </DIV>
+   </xsl:template>
+
+   <!-- match attributes -->
+   <xsl:template match="@*">
+      <SPAN class="an">
+         <xsl:value-of select="name(.)"/>
+      </SPAN>
+      <SPAN class="m">="</SPAN>
+      <SPAN class="av">
+         <xsl:value-of select="."/>
+      </SPAN>
+      <SPAN class="m">"</SPAN>
+      <xsl:if test="position()!=last()">
+         <xsl:text> </xsl:text>
+      </xsl:if>
+   </xsl:template>
+
+   <!-- match empty elements -->
+   <xsl:template match="*[not(node())]">
+      <DIV class="e">
+        <SPAN class="m">&lt;</SPAN>
+        <SPAN class="en">
+           <xsl:value-of select="name(.)"/>
+        </SPAN>
+        <xsl:if test="@*">
+           <xsl:text> </xsl:text>
+        </xsl:if>
+        <xsl:apply-templates select="@*"/>
+        <xsl:apply-templates select="." mode="namespace"/>
+        <SPAN class="m">/&gt;</SPAN>
+      </DIV>
+   </xsl:template>
+
+   <!-- match elements with only text(), they are not closeable -->
+   <xsl:template match="*[text()][not(* or comment() or processing-instruction())]" priority="10">
+      <DIV class="e">
+        <SPAN class="m">&lt;</SPAN>
+        <SPAN class="en">
+           <xsl:value-of select="name(.)"/>
+        </SPAN>
+        <xsl:if test="@*">
+           <xsl:text> </xsl:text>
+        </xsl:if>
+        <xsl:apply-templates select="@*"/>
+        <xsl:apply-templates select="." mode="namespace"/>
+        <SPAN class="m">
+           <xsl:text>></xsl:text>
+        </SPAN>
+        <SPAN class="t">
+           <xsl:value-of select="."/>
+        </SPAN>
+        <SPAN class="m">&lt;/</SPAN>
+        <SPAN class="en">
+           <xsl:value-of select="name(.)"/>
+        </SPAN>
+        <SPAN class="m">
+           <xsl:text>></xsl:text>
+        </SPAN>
+      </DIV>
+   </xsl:template>
+
+   <xsl:template match="*[node()]">
+      <DIV class="e">
+         <DIV>
+            <SPAN class="b" onclick="xml2htmlToggle(event)">-</SPAN>
+            <SPAN class="m">&lt;</SPAN>
+            <SPAN class="en">
+               <xsl:value-of select="name(.)"/>
+            </SPAN>
+            <xsl:if test="@*">
+               <xsl:text> </xsl:text>
+            </xsl:if>
+            <xsl:apply-templates select="@*"/>
+            <xsl:apply-templates select="." mode="namespace"/>
+            <SPAN class="m">
+               <xsl:text>></xsl:text>
+            </SPAN>
+         </DIV>
+         <DIV>
+            <xsl:apply-templates/>
+            <DIV>
+               <SPAN class="m">&lt;/</SPAN>
+               <SPAN class="en">
+                  <xsl:value-of select="name(.)"/>
+               </SPAN>
+               <SPAN class="m">
+                  <xsl:text>></xsl:text>
+               </SPAN>
+            </DIV>
+         </DIV>
+      </DIV>
+   </xsl:template>
+
+   <xsl:template match="*" mode="namespace">
+     <xsl:variable name="context" select="."/>
+     <xsl:for-each select="namespace::node()">
+       <xsl:variable name="nsuri" select="."/>
+       <xsl:variable name="nsprefix" select="name()"/>
+       <xsl:choose>
+        <xsl:when test="$nsprefix = 'xml'">
+          <!-- xml namespace -->
+        </xsl:when>
+        <xsl:when test="$context/../namespace::node()[name() = $nsprefix and . = $nsuri]">
+          <!-- namespace already declared on the parent -->
+        </xsl:when>
+        <xsl:otherwise>
+          <xsl:text> </xsl:text>
+          <SPAN class="an">
+            <xsl:text>xmlns</xsl:text>
+            <xsl:if test="$nsprefix">
+              <xsl:text>:</xsl:text>
+              <xsl:value-of select="$nsprefix"/>
+            </xsl:if>
+          </SPAN>
+          <SPAN class="m">="</SPAN>
+          <SPAN class="av">
+            <xsl:value-of select="."/>
+          </SPAN>
+          <SPAN class="m">"</SPAN>
+        </xsl:otherwise>
+       </xsl:choose>
+     </xsl:for-each>
+   </xsl:template>
+
+</xsl:stylesheet>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/stylesheets/system/xml2html.xslt
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/sitemap.xmap
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/sitemap.xmap?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/sitemap.xmap (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/sitemap.xmap Thu Nov  3 05:41:06 2005
@@ -0,0 +1,64 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!-- CVS $Id: sitemap.xmap 30946 2004-07-29 20:44:21Z vgritsenko $ -->
+
+<map:sitemap xmlns:map="http://apache.org/cocoon/sitemap/1.0">
+
+<!-- =========================== Components ================================ -->
+
+ <map:components>
+  <map:generators default="file"/>
+  <map:transformers default="xslt"/>
+  <map:readers default="resource"/>
+  <map:serializers default="html"/>
+  <map:matchers default="wildcard"/>
+  <map:selectors default="browser"/>
+ </map:components>
+
+<!-- =========================== Views =================================== -->
+
+ <map:views>
+  <map:view name="content" from-label="content">
+   <map:serialize type="xml"/>
+  </map:view>
+
+  <map:view from-label="content" name="pretty-content">
+    <map:transform src="context://stylesheets/system/xml2html.xslt"/>
+    <map:serialize type="html"/>
+  </map:view>
+
+  <map:view name="links" from-position="last">
+   <map:serialize type="links"/>
+  </map:view>
+ </map:views>
+
+<!-- =========================== Pipelines ================================= -->
+
+ <map:pipelines>
+  <map:pipeline>
+
+   <map:match pattern="static-site/**.html">
+     <map:generate src="xdocs/{1}.xml"/>
+     <map:transform src="stylesheets/xdoc2html.xslt">
+      <map:parameter name="contextPath" value="{request:contextPath}"/>
+     </map:transform>
+     <map:serialize type="html"/>
+   </map:match>
+   </map:pipeline>
+ </map:pipelines>
+</map:sitemap>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/sitemap.xmap
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/stylesheets/simple-xdoc2html.xslt
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/stylesheets/simple-xdoc2html.xslt?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/stylesheets/simple-xdoc2html.xslt (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/stylesheets/simple-xdoc2html.xslt Thu Nov  3 05:41:06 2005
@@ -0,0 +1,95 @@
+<?xml version="1.0"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!--+
+    | Converts output of the StatusGenerator into HTML page
+    | 
+    | CVS $Id: simple-xdoc2html.xslt,v 1.1 2004/04/28 21:29:08 upayavira Exp $
+    +-->
+
+<xsl:stylesheet version="1.0"
+                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns:status="http://apache.org/cocoon/status/2.0">
+ 
+  <xsl:param name="contextPath"/>
+
+  <xsl:template match="status:statusinfo">
+    <html>
+      <head>
+        <title>Cocoon Status [<xsl:value-of select="@status:host"/>]</title>
+        <link href="{$contextPath}/styles/main.css" type="text/css" rel="stylesheet"/>
+        <script src="{$contextPath}/scripts/main.js" type="text/javascript"/>
+      </head>
+
+      <body>
+        <h1><xsl:value-of select="@status:host"/> - <xsl:value-of select="@status:date"/></h1>
+        <xsl:apply-templates/>
+      </body>
+    </html>
+  </xsl:template>
+
+  <xsl:template match="status:group">
+    <h2><xsl:value-of select="@status:name"/></h2>
+    <ul><xsl:apply-templates select="status:value"/></ul>
+    <xsl:apply-templates select="status:group"/>
+  </xsl:template>
+
+  <xsl:template match="status:value">
+    <li>
+      <span class="description"><xsl:value-of select="@status:name"/><xsl:text>: </xsl:text></span>
+      <xsl:choose>
+        <xsl:when test="contains(@status:name,'free') or contains(@status:name,'total')">
+          <xsl:call-template name="suffix">
+            <xsl:with-param name="bytes" select="number(.)"/>
+          </xsl:call-template>
+        </xsl:when>      
+        <xsl:when test="count(status:line) &lt;= 1">
+          <xsl:value-of select="status:line"/>
+        </xsl:when>
+        <xsl:otherwise>
+          <span class="switch" id="{generate-id(.)}-switch" onclick="toggle('{generate-id(.)}')">[show]</span>
+          <ul id="{generate-id(.)}" style="display: none">
+             <xsl:apply-templates />
+          </ul>
+        </xsl:otherwise>
+      </xsl:choose>
+    </li>
+  </xsl:template>
+
+  <xsl:template match="status:line">
+    <li><xsl:value-of select="."/></li>
+  </xsl:template>
+
+  <xsl:template name="suffix">
+    <xsl:param name="bytes"/>
+    <xsl:choose>
+      <!-- More than 4 MB (=4194304) -->
+      <xsl:when test="$bytes &gt;= 4194304">
+        <xsl:value-of select="round($bytes div 10485.76) div 100"/> MB
+      </xsl:when>
+      <!-- More than 4 KB (=4096) -->
+      <xsl:when test="$bytes &gt; 4096">
+        <xsl:value-of select="round($bytes div 10.24) div 100"/> KB
+      </xsl:when>
+      <!-- Less -->
+      <xsl:otherwise>
+        <xsl:value-of select="$bytes"/> B
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  
+</xsl:stylesheet>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/stylesheets/simple-xdoc2html.xslt
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/xdocs/index.xml
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/xdocs/index.xml?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/xdocs/index.xml (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/xdocs/index.xml Thu Nov  3 05:41:06 2005
@@ -0,0 +1,40 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+<!DOCTYPE document PUBLIC "-//APACHE//DTD Documentation V1.0//EN" "dtd/document-v10.dtd">
+<document>
+  <header>
+    <title>Cocoon TestSuite</title>
+    <authors>
+      <person name="Cocoon community" email="dev@cocoon.apache.org"/>
+    </authors>
+  </header>
+  <body>
+    <s1 title="General information">
+      <p>
+          Apache Cocoon is a web development framework built around the concepts 
+          of component-based web development and separation of concerns, ensuring 
+          that people can interact and collaborate on a project without stepping 
+          on each other toes.
+      </p>
+      <p>
+          The purpose of these pages is to provide a webapp to be used in testing
+          Cocoon itself. These pages are not intended to be read by humans - rather
+          to be read by automated tests that are a part of Cocoon itself.
+      </p>
+    </s1>    
+  </body>
+</document>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/test-suite/xdocs/index.xml
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xml
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xml?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xml (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xml Thu Nov  3 05:41:06 2005
@@ -0,0 +1,30 @@
+<?xml version="1.0"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!--+
+    | This is a very simple XML page done just to show how a simple 
+    | cocoon pipeline works.
+    |
+    | CVS $Id: welcome.xml 30942 2004-07-29 20:16:54Z vgritsenko $
+    +-->
+
+<welcome>
+ <message>
+   Congratulations! If you are reading this page, it means that
+   your Apache Cocoon installation was successful.
+ </message>
+</welcome>
\ No newline at end of file

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xml
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xslt
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xslt?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xslt (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xslt Thu Nov  3 05:41:06 2005
@@ -0,0 +1,62 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+-->
+
+<!-- CVS $Id: welcome.xslt,v 1.11 2004/03/06 02:25:58 antonio Exp $ -->
+
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                              xmlns="http://www.w3.org/1999/xhtml">
+
+  <xsl:param name="contextPath"/>
+
+  <xsl:template match="welcome">
+    <html xml:lang="en" lang="en">
+      <head>
+        <title>Welcome to Apache Cocoon!</title>
+        <!-- 
+             NOTE (SM): this meta tag reflects the *output* of the pipeline and not
+             the encoding of this file. I agree it's sort of an hack and it should
+             be the XHTML serializer to add the meta tag to the response, but, for
+             now, this fixes encoding problems in those user-agents that don't parse
+             the <?xml?> processing instruction to understand the encoding of the
+             stream 
+         --> 
+        <meta http-equiv="Content-Type" content="text/xhtml; charset=UTF-8"/>
+        <link href="{$contextPath}/styles/main.css" type="text/css" rel="stylesheet"/>
+        <link href="favicon.ico" rel="SHORTCUT ICON" />
+      </head>
+      <body>
+        <h1>Welcome to Apache Cocoon!</h1>
+        <xsl:apply-templates/>
+        <p class="copyright">
+         Copyright © @year@ <a href="http://www.apache.org/">The Apache Software Foundation</a>. All rights reserved.
+        </p>
+        <p class="block">
+          <a href="http://cocoon.apache.org/"><img src="{$contextPath}/images/powered.gif" alt="Powered by Apache Cocoon"/></a>
+        </p>
+      </body>
+    </html>
+  </xsl:template>
+
+  <xsl:template match="message">
+    <p class="block"><xsl:apply-templates/></p>
+  </xsl:template>
+  
+  <xsl:template match="link">
+    <a href="{@href}"><xsl:apply-templates/></a>
+  </xsl:template>
+
+</xsl:stylesheet>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/welcome.xslt
------------------------------------------------------------------------------
    svn:eol-style = native

Added: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/wiring.xml
URL: http://svn.apache.org/viewcvs/cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/wiring.xml?rev=330548&view=auto
==============================================================================
--- cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/wiring.xml (added)
+++ cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/wiring.xml Thu Nov  3 05:41:06 2005
@@ -0,0 +1,32 @@
+<!--
+  Copyright 1999-2004 The Apache Software Foundation
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License. 
+-->
+<wiring xmlns="http://apache.org/cocoon/blocks/wiring/1.0"
+        xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
+        xsi:schemaLocation="http://apache.org/cocoon/blocks/wiring/1.0 wiring-schema-1.0.xsd"
+>
+
+  <block id="sampleid" location="WEB-INF/blocks/sample/">
+    <mount path="/blocks-test/sample/"/>
+  </block>
+
+  <block id="mysample" location="WEB-INF/blocks/mysample/">
+    <mount path="/blocks-test/mysample/"/>
+    <connections>
+      <connection name="super" block="sampleid"/>
+    </connections>
+  </block>
+
+</wiring>

Propchange: cocoon/whiteboard/maven2/cocoon-flat-layout/webapp/src/main/webapp/wiring.xml
------------------------------------------------------------------------------
    svn:eol-style = native



Mime
View raw message